Pista circolare

L’area della pista circolare è uguale all’area del cerchio con diametro AB.
AB è una corda del cerchio maggiore tangente al cerchio minore.

• Mouse (posizione): cambia la figura
• Mouse (tasto): rivela la proprietà
• Applicazione Java

color fSfondo, 
      fPrimo, 
      fSecondo, 
      sPrimo, 
      sSecondo, 
      cLettere;   
int   dx, dy; 
float D1x, D2x, DDx, DDy, DDr, DDr2,
      Ax,  Bx,  ABx, ABy, ABr;  
PFont fontLettere;

void setup()
{
   size(500, 500); 
   ellipseMode(CENTER_RADIUS); 
   smooth(); 
   fontLettere=loadFont("C16.vlw");
   textFont(fontLettere);
   textAlign(CENTER);

   fSfondo=color(255, 255, 255);
   fPrimo=color(0, 0, 0);         
   sPrimo=color(0);
   fSecondo=color(0, 255, 0, 50); 
   sSecondo=color(0, 255, 0);  
   cLettere=color(0, 0, 255);          

   dx=width; 
   dy=height;
   DDx=dx/2; 
   DDy=dy*0.57; 
   DDr=dx*0.37;             
   ABx=DDx;

   noLoop();
}

void mousePressed() { redraw(); }
void mouseMoved()   { redraw(); }
void mouseDragged() { redraw(); }

void aggiorna()
{
   DDr2=abs(DDx-constrain(mouseX, DDx-DDr, DDx+DDr));
   ABy=DDy-DDr2;
   ABr=sqrt(DDr*DDr-DDr2*DDr2);
   Ax=DDx-ABr;
   Bx=DDx+ABr;
}

void draw()
{
  aggiorna();  
  background(fSfondo);
  smooth();  

  noStroke();       
    fill(fPrimo);   
    ellipse(DDx, DDy, DDr, DDr);
  strokeWeight(2);
    stroke(fSfondo);  
    fill(fSfondo);  
    ellipse(DDx, DDy, DDr2, DDr2);

  if(mousePressed)
  {
    stroke(sSecondo); 
      fill(fSecondo); 
      ellipse(ABx, ABy, ABr, ABr);
    strokeWeight(1);
      stroke(sSecondo);                 
      line(Ax, ABy, Bx, ABy);
      line(Bx, ABy, DDx, DDy);
      line(DDx, ABy, DDx, DDy);
    strokeWeight(2);
      stroke(cLettere); 
      fill(cLettere); 
      ellipse(Ax, ABy, 2, 2);                   
      ellipse(Bx, ABy, 2, 2);
      ellipse(DDx, DDy, 2, 2);
      ellipse(ABx, ABy, 2, 2);                                    
      text("A", Ax-20, ABy-20);              
      text("B", Bx+20, ABy-20);
      text("O", DDx+20, DDy+20);
      text("O'", ABx-20, ABy+20);
  }
}

Siano

• r=|OB|, raggio del cerchio maggiore
• r₁=|OO’|, raggio del cerchio minore
• r₂=|O’B|, raggio del cerchio con area uguale all’area della pista circolare

allora

r²-r₁²=r₂²
π*r²-π*r₁²=π*r₂²